build.clj

(ns build
  "This is the build script for the usermanager project.

   You can use this command to get a list of (public) functions in build.clj:

     clojure -T:deps:build help/dir

   You can use this command to get documentation for a specific function:

     clojure -T:deps:build help/doc :fn ci

   The :deps alias is provided by the Clojure CLI and provides some useful
   tooling when working with projects. This will list deps functions:

     clojure -T:deps help/dir

   and this will list the functions available in the help ns (alias):

     clojure -T:deps help/dir :ns help"
  (:refer-clojure :exclude [test])
  (:require [clojure.tools.build.api :as b]))

(def lib 'usermanager/example)
(def main 'usermanager.main)
(def class-dir "target/classes")

(defn test "Run all the tests." [opts]
  (let [basis    (b/create-basis {:aliases [:test]})
        cmds     (b/java-command
                  {:basis     basis
                   :main      'clojure.main
                   :main-args ["-m" "cognitect.test-runner"]})
        {:keys [exit]} (b/process cmds)]
    (when-not (zero? exit) (throw (ex-info "Tests failed" {:exit exit}))))
  opts)

(defn- uber-opts [opts]
  (assoc opts
         :lib lib :main main
         :uber-file (format "target/%s-standalone.jar" lib)
         :basis (b/create-basis {})
         :class-dir class-dir
         :src-dirs ["src"]
         :ns-compile [main]))

(defn ci "Run the CI pipeline of tests (and build the uberjar)." [opts]
  (test opts)
  (b/delete {:path "target"})
  (let [opts (uber-opts opts)]
    (println "\nCopying source...")
    (b/copy-dir {:src-dirs ["resources" "src"] :target-dir class-dir})
    (println (str "\nCompiling " main "..."))
    (b/compile-clj opts)
    (println "\nBuilding JAR..." (:uber-file opts))
    (b/uber opts))
  opts)