build.gradle

plugins {
	id("net.twisterrob.inventory.root")
}

tasks.register("clean", Delete.class) { clean ->
	clean.dependsOn(gradle.includedBuilds*.task(":cleanFull"))
	clean.delete(project.layout.buildDirectory)
}

tasks.register("build") { build ->
	build.dependsOn(gradle.includedBuilds*.task(":build"))
}

idea {
	module {
		excludeDirs += [
				// local untracked folder for junk
				rootProject.file("temp"),
				rootProject.file("android/src/main/future"),
		]
	}
}

// TODEL https://issuetracker.google.com/issues/222730176
// This makes sure to pick up all subprojects not just direct children.
// com.android.build.gradle.internal.plugins.ReportingPlugin reads the subprojects in afterEvaluate,
// so this will run at the right time for it to observe evaluated children.
subprojects.forEach { evaluationDependsOn(it.path) } // evaluationDependsOnSubprojects()
// https://developer.android.com/studio/test/command-line#multi-module-reports-instrumented-tests
apply(plugin: "android-reporting")
afterEvaluate {
	tasks.named("mergeAndroidReports").configure {
		mustRunAfter(dependsOn)
		setDependsOn([ ])
		doFirst {
			resultsDirectories.removeIf { !it.exists() }
		}
	}
}